rustgn

_cc = rebase_path("//.tools/gcc", root_build_dir)
_cxx = rebase_path("//.tools/c++", root_build_dir)
_ar = rebase_path("//.tools/ar", root_build_dir)
_rustc = rebase_path("//.tools/rustc", root_build_dir)

toolchain("build") {
    tool("cc") {
        depfile = "{{output}}.d"
        command = "$_cc -MMD -MF $depfile {{defines}} {{include_dirs}} {{cflags}} {{cflags_c}} -c {{source}} -o {{output}}"
        depsformat = "gcc"
        description = "CC {{output}}"
        outputs = [ "{{source_out_dir}}/{{source_name_part}}.o" ]
    }

    tool("cxx") {
        depfile = "{{output}}.d"
        command = "$_cxx -MMD -MF $depfile {{defines}} {{include_dirs}} {{cflags}} {{cflags_cc}} -c {{source}} -o {{output}}"
        depsformat = "gcc"
        description = "CXX {{output}}"
        outputs = [ "{{source_out_dir}}/{{source_name_part}}.o" ]
    }

    tool("alink") {
        command = "rm -f {{output}} && $_ar rcs {{output}} {{inputs}}"
        description = "AR {{output}}"
        outputs = [ "{{output_dir}}/{{target_output_name}}{{output_extension}}" ]
        default_output_dir = "{{root_out_dir}}"
        default_output_extension = ".a"
        output_prefix = "lib"
    }

    tool("solink") {
        outfile = "{{output_dir}}/{{target_output_name}}{{output_extension}}"
        command = "$_cxx -shared {{ldflags}} -o $outfile -Wl,-soname={{target_output_name}}{{output_extension}} {{inputs}} {{libs}} {{solibs}}"
        description = "SOLINK $outfile"
        outputs = [ outfile ]
        default_output_dir = "{{root_out_dir}}"
        default_output_extension = ".so"
        output_prefix = "lib"
    }

    tool("link") {
        outfile = "{{output_dir}}/{{target_output_name}}{{output_extension}}"
        command = "$_cxx {{ldflags}} -o $outfile {{inputs}} {{libs}} {{solibs}}"
        description = "LINK $outfile"
        outputs = [ outfile ]
        default_output_dir = "{{root_out_dir}}"
    }

    tool("stamp") {
        command = "touch {{output}}"
        description = "STAMP {{output}}"
    }

    tool("copy") {
        command = "cp -af {{source}} {{output}}"
        description = "COPY {{source}} {{output}}"
    }

    tool("rust_bin") {
        outfile = "{{root_out_dir}}/{{crate_name}}"
        depfile = "$outfile.d"
        command = "$_rustc --emit=dep-info=$depfile,link {{rustenv}} {{source}} --crate-name={{crate_name}} --crate-type=bin {{rustflags}} {{rustdeps}} {{externs}} -o $outfile"
        description = "RUSTC $outfile"
        outputs = [ outfile ]
    }

    tool("rust_rlib") {
        outfile = "{{output_dir}}/lib{{crate_name}}.rlib"
        depfile = "$outfile.d"
        command = "$_rustc --emit=dep-info=$depfile,link {{rustenv}} {{source}} --crate-name={{crate_name}} --crate-type=rlib {{rustflags}} {{rustdeps}} {{externs}} -o $outfile"
        description = "RUSTC $outfile"
        outputs = [ outfile ]
        default_output_dir = "{{root_out_dir}}"
    }

    tool("rust_macro") {
        outfile = "{{output_dir}}/lib{{crate_name}}.so"
        depfile = "$outfile.d"
        command = "$_rustc --emit=dep-info=$depfile,link {{rustenv}} {{source}} --crate-name={{crate_name}} --crate-type=proc-macro --extern proc_macro {{rustflags}} -Clto=off {{rustdeps}} {{externs}} -o $outfile"
        description = "RUSTC $outfile"
        outputs = [ outfile ]
        default_output_dir = "{{root_out_dir}}"
    }
}

toolchain("check") {
    tool("cc") {
        depfile = "{{output}}.d"
        command = "$_cc -MMD -MF $depfile {{defines}} {{include_dirs}} {{cflags}} {{cflags_c}} -c {{source}} -o {{output}}"
        depsformat = "gcc"
        description = "CC {{output}}"
        outputs = [ "{{source_out_dir}}/{{source_name_part}}.o" ]
    }

    tool("cxx") {
        depfile = "{{output}}.d"
        command = "$_cxx -MMD -MF $depfile {{defines}} {{include_dirs}} {{cflags}} {{cflags_cc}} -c {{source}} -o {{output}}"
        depsformat = "gcc"
        description = "CXX {{output}}"
        outputs = [ "{{source_out_dir}}/{{source_name_part}}.o" ]
    }

    tool("alink") {
        command = "rm -f {{output}} && $_ar rcs {{output}} {{inputs}}"
        description = "AR {{output}}"
        outputs = [ "{{output_dir}}/{{target_output_name}}{{output_extension}}" ]
        default_output_dir = "{{root_out_dir}}"
        default_output_extension = ".a"
        output_prefix = "lib"
    }

    tool("solink") {
        outfile = "{{output_dir}}/{{target_output_name}}{{output_extension}}"
        command = "$_cxx -shared {{ldflags}} -o $outfile -Wl,-soname={{target_output_name}}{{output_extension}} {{inputs}} {{libs}} {{solibs}}"
        description = "SOLINK $outfile"
        outputs = [ outfile ]
        default_output_dir = "{{root_out_dir}}"
        default_output_extension = ".so"
        output_prefix = "lib"
    }

    tool("link") {
        outfile = "{{output_dir}}/{{target_output_name}}{{output_extension}}"
        command = "$_cxx {{ldflags}} -o $outfile {{inputs}} {{libs}} {{solibs}}"
        description = "LINK $outfile"
        outputs = [ outfile ]
        default_output_dir = "{{root_out_dir}}"
    }

    tool("stamp") {
        command = "touch {{output}}"
        description = "STAMP {{output}}"
    }

    tool("copy") {
        command = "cp -af {{source}} {{output}}"
        description = "COPY {{source}} {{output}}"
    }

    tool("rust_bin") {
        outfile = "{{root_out_dir}}/{{crate_name}}.rmeta"
        depfile = "$outfile.d"
        command = "$_rustc --emit=dep-info=$depfile,metadata --error-format=json {{rustenv}} {{source}} --crate-name={{crate_name}} --crate-type=bin {{rustflags}} {{rustdeps}} {{externs}} -o $outfile"
        description = "CHECK $outfile"
        outputs = [ outfile ]
    }

    tool("rust_rlib") {
        outfile = "{{output_dir}}/lib{{crate_name}}.rmeta"
        depfile = "$outfile.d"
        command = "$_rustc --emit=dep-info=$depfile,metadata --error-format=json {{rustenv}} {{source}} --crate-name={{crate_name}} --crate-type=rlib {{rustflags}} {{rustdeps}} {{externs}} -o $outfile"
        description = "CHECK $outfile"
        outputs = [ outfile ]
        default_output_dir = "{{root_out_dir}}"
    }

    tool("rust_macro") {
        outfile = "{{output_dir}}/lib{{crate_name}}.so"
        depfile = "$outfile.d"
        command = "$_rustc --emit=dep-info=$depfile,link --error-format=json {{rustenv}} {{source}} --crate-name={{crate_name}} --crate-type=proc-macro --extern proc_macro {{rustflags}} {{rustdeps}} {{externs}} -o $outfile"
        description = "CHECK $outfile"
        outputs = [ outfile ]
        default_output_dir = "{{root_out_dir}}"
    }
}